値は，スカラー式によって表現されます。スカラー式で表現できる値は，プロパティの指定，ルーチン起動，数値関数および集合関数によって得られる値です。

形式

!! <プロパティ指定>の形式
<プロパティ指定> ::= 〔<プロパティ修飾子> <ピリオド>〕 <プロパティ名>
<プロパティ修飾子> ::= <相関名>     !! <相関名>による修飾
　　　　　　　　　　 ｜<クラス指定> !! <クラス指定>による修飾
　
!! <要素参照>の形式
<要素参照> ::= <一次子>
                <左角括弧> ANY <右角括弧>
　
!! <フィールド参照>の形式
<フィールド参照> ::= <要素参照> <ピリオド> <フィールド名>
<フィールド名> ::= <プロパティ名>
　
!! <ルーチンの起動>の形式
<ルーチンの起動> ::= <ルーチン名> <引数リスト>
<引数リスト> ::= <左括弧> 〔 <引数>
　　　　　　　　　　〔 { <コンマ> <引数> }... 〕 〕 <右括弧>
<引数> ::=  <値式>
　　　　　｜<値式> AS <データ型指定>
<ルーチン名> ::= <関数指定>
　
<データ型指定> ::= INT
　　　　　　　　 ｜INTEGER
　　　　　　　　 ｜BOOL
　　　　　　　　 ｜BOOLEAN
　　　　　　　　 ｜STRING <左括弧> <符号なし数値> <右括弧>
　　　　　　　　 ｜BINARY <左括弧> <バイナリ長> <右括弧>
　
<バイナリ長> ::=  <符号なし数値>
　　　　　　　　｜<バイナリ長トークン>
　
!! <数値関数>の形式
<数値関数> ::= <絶対値関数>
<絶対値関数> ::= ABS <左括弧> <値式> <右括弧>
　
!! <集合関数>の形式
<集合関数> ::= COUNT <左括弧> <アスタリスク> <右括弧>
　　　　　　 ｜<一般集合関数>
<一般集合関数> ::= <集合関数種別>
　　　　　　　　　 <左括弧> 〔 <集合指定子> 〕 <値式> <右括弧>
<集合関数種別> ::= COUNT
<集合指定子> ::= DISTINCT｜ALL
　
!! <値式>の形式
<値式> ::= <一次子>
　　　　　｜<符号> <一次子>
　　　　　｜<値式> <+符号> <値式>
　　　　　｜<値式> <-符号> <値式>
　　　　　｜<値式> <アスタリスク> <値式>
　　　　　｜<値式> <斜線> <値式>
　　　　　｜<値式> <文字列連結演算子> <値式>
<一次子> ::= <左括弧> <値式> <右括弧>
　　　　　 ｜<プロパティ指定>
　　　　　 ｜<符号なし値指定>
　　　　　 ｜<集合関数>
　　　　　 ｜<数値関数>
　　　　　 ｜<ルーチンの起動>
　　　　　 ｜<フィールド参照>
<符号なし値指定> ::= <符号なし数値リテラル>
　　　　　　　　　　｜<文字列リテラル>
　　　　　　　　　　｜<疑問符>
　　　　　　　　　　｜<論理リテラル>
<値指定> ::= 〔<符号>〕<符号なし数値リテラル>
　　　　　　｜<文字列リテラル>
　　　　　　｜<疑問符>
　　　　　　｜<論理リテラル>

＜この節の構成＞

2.7.1　<プロパティ指定>

2.7.2　<要素参照>

2.7.3　<フィールド参照>

2.7.4　<ルーチンの起動>

2.7.5　<数値関数>

2.7.6　<集合関数>

2.7.7　<値式>