Tiered Storage Manager Software CLI リファレンスガイド

4.2 検索条件式の構文

検索条件式の構文をBNFで次に示します。

storage-tier-filter-condition ::= and-search-condition
                               | or-search-condition
and-search-condition ::= comparison-predicate
                      | and-search-condition "AND" and-search-condition
                      | "(" and-search-condition ")"
or-search-condition ::= comparison-predicate
                      | or-search-condition "OR" or-search-condition
                      | "(" or-search-condition ")"
  
volume-filter-condition ::= term | volume-filter-condition "OR" volume-filter-condition
term ::= factor | term "AND" term
factor ::= test | "NOT" factor
test ::= comparison-predicate | "(" volume-filter-condition ")"
  
pool-filter-condition ::= pool-term | pool-filter-condition "OR" pool-filter-condition
pool-term ::= pool-factor | pool-term "AND" pool-term
pool-factor ::= pool-test | "NOT" pool-factor
pool-test ::= comparison-predicate | "(" pool-filter-condition ")"
  
unused-capacity-filter-condition ::= unused-capacity-term
       | unused-capacity-filter-condition "OR" unused-capacity-filter-condition
unused-capacity-term ::= unused-capacity-factor
                 | unused-capacity-term "AND" unused-capacity-term
unused-capacity-factor ::= unused-capacity-test | "NOT" unused-capacity-factor
unused-capacity-test ::= comparison-predicate
                 | "(" unused-capacity-filter-condition ")"
  
comparison-predicate ::= symbol comp-op literal
symbol ::= name
comp-op ::= "=" | "<>" | "<" | ">" | "<=" | ">=" | "startsWith"
            | "contains"| "endsWith"
literal ::= string-literal | numeric-literal
numeric-literal ::= digit { digit }
digit ::= "0" | "1" | "2" | "3" | "4" | "5" | "6" | "7" | "8" | "9"

繰り返し指定について次に示します。

中括弧 { } は，0回以上の繰り返しを表します。
1つの検索条件式に最大30個のcomparison-predicateを記述できます。

重要: literalには，「値が不明」であることを指定できません。値が不明である場合も文字列の"Unknown"である場合も，どちらも"Unknown"と表示されることがあります。

comp-opの種類と意味を次に示します。

=：等しいことを示します。
<>：等しくないことを示します。
startsWith：指定文字列で始まる値を検索することを示します。
endsWith：指定文字列で終わる値を検索することを示します。
contains：指定文字列を含む値を検索することを示します。

この節の構成: 4.2.1 string-literalの記述形式; 4.2.2 複数の要素を指定できるプロパティの記述規則

[目次] [前へ] [次へ]