トランザクショナル分散オブジェクト基盤　TPBroker Object Transaction Monitor　プログラマーズガイド

[目次][索引][前へ][次へ]

6.7.1　ユーザ例外通知を利用するクライアントアプリケーションの例（COBOL）

ユーザ例外通知を利用するクライアントアプリケーションの処理の流れとコードの例を示します。太字で示しているコードは，同期型呼び出しのコードと異なる部分です。

なお，ユーザ例外通知を利用するクライアントアプリケーションの例外処理は，同期型呼び出しの場合と同様です。「6.2.3　例外処理のコードの例（COBOL）」を参照してください。

＜この項の構成＞
(1)　サービス利用処理の流れ
(2)　サービス利用処理のコード

(1)　サービス利用処理の流れ

  1. COBOL adapter for TPBrokerの初期化処理
  2. TPBroker OTMの初期化処理
  3. TSCデーモンへの接続
  4. TSCユーザプロキシの生成および各種設定
  5. TSCユーザプロキシのメソッド呼び出し（サーバ側のオブジェクトの呼び出し）
  6. TSCユーザプロキシの削除
  7. TSCデーモンへの接続解放
  8. TPBroker OTMの終了処理

(2)　サービス利用処理のコード

 
       IDENTIFICATION DIVISION.
       PROGRAM-ID. CLIENT.
       ENVIRONMENT DIVISION.
       CONFIGURATION SECTION.
 
       DATA DIVISION.
       WORKING-STORAGE SECTION.
 
       01 ORB-PTR               USAGE POINTER.
       01 DOMAIN-PTR            USAGE POINTER.
       01 CLIENT-PTR            USAGE POINTER.
       01 CLIENT-WAY            PIC S9(9) COMP.
       01 MY-DOMAIN-NAME        PIC X(10).
       01 MY-DOMAIN-NAME-PTR    USAGE POINTER.
       01 MY-DOMAIN-NAME-LEN    PIC S9(9) COMP.
       01 MY-TSCID              PIC X(10).
       01 MY-TSCID-PTR          USAGE POINTER.
       01 MY-TSCID-LEN          PIC S9(9) COMP.
       01 MY-DOMAIN-FLAG        PIC S9(9) COMP VALUE 1.
       01 ACCEPTOR-NAME         PIC X(20).
       01 ACCEPTOR-NAME-PTR     USAGE POINTER VALUE NULL.
       01 ACCEPTOR-NAME-LEN     PIC S9(9) COMP.
       01 PROXY-PTR             USAGE POINTER.
 
       01 INIT-CLIENT-FLAG      PIC S9(9) COMP.
       01 DOMAIN-CREATE-FLAG    PIC S9(9) COMP.
       01 GET-CLIENT-FLAG       PIC S9(9) COMP.
       01 TSCPRXY-CREATE-FLAG   PIC S9(9) COMP.
 
       01 CORBA-ENVIRONMENT.
        02 MAJOR                PIC 9(9) COMP.
         88 CORBA-NO-EXCEPTION     VALUE 0.
         88 CORBA-USER-EXCEPTION   VALUE 1.
         88 CORBA-SYSTEM-EXCEPTION VALUE 2.
        02 EXCEP                USAGE POINTER.
        02 FUNC-NAME            PIC X(256).
 
       01 ERR-CODE              PIC S9(9) COMP.
 
      * Sequence
       01 EXCEPTION-NAME-PTR        USAGE POINTER.
       01 EXCEPTION-NAME-LEN        PIC S9(9) COMP.
       01 EXCEPTION-NAME            PIC X(30).
       01 EXCEPTION-HANDLE          USAGE POINTER.
       01 EXCEPTION-VALUE           PIC S9(9) COMP.
 
       LINKAGE SECTION.
       01 ARGC                  PIC 9(9) COMP.
       01 ARGV                  USAGE POINTER.
 
       PROCEDURE DIVISION USING
               BY VALUE ARGC
               BY VALUE ARGV.
 
       MOVE 0 TO RETURN-CODE.
       MOVE 0 TO INIT-CLIENT-FLAG.
       MOVE 0 TO DOMAIN-CREATE-FLAG.
       MOVE 0 TO GET-CLIENT-FLAG.
       MOVE 0 TO TSCPRXY-CREATE-FLAG.
 
      * ORBの初期化処理
       CALL 'CORBA-STUB-INIT-EEEfile'.
 
      * 1. COBOL adapter for TPBrokerの初期化処理
       CALL 'CORBA_orb_init' USING
               BY REFERENCE ARGC
               BY REFERENCE ARGV
               BY REFERENCE CORBA-ENVIRONMENT
           RETURNING ORB-PTR.
      * 例外チェック
       IF NOT CORBA-NO-EXCEPTION THEN
           CALL 'EXCEPTION-HANDLER' USING
                   BY REFERENCE MAJOR
                   BY REFERENCE CORBA-ENVIRONMENT
           CALL 'CORBA_FreeException' USING
                   EXCEP OF CORBA-ENVIRONMENT
           MOVE 1 TO RETURN-CODE
           GO TO PROG-END
       END-IF.
       DISPLAY 'Success CORBA_orb_init'.
 
      * 2. TPBroker OTMの初期化処理
       CALL 'TSCAdm-initClient' USING 
               BY REFERENCE ARGC
               BY REFERENCE ARGV
               BY VALUE     ORB-PTR
               BY REFERENCE CORBA-ENVIRONMENT.
      * 例外チェック
       IF NOT CORBA-NO-EXCEPTION THEN
           CALL 'OTM-EXCEPTION-HANDLER' USING
                   BY REFERENCE MAJOR
                   BY REFERENCE CORBA-ENVIRONMENT
           CALL 'TSCSysExcept-DELETE' USING
                   BY VALUE EXCEP OF CORBA-ENVIRONMENT
           MOVE 1 TO RETURN-CODE
           GO TO PROG-END
       END-IF.
       DISPLAY 'Success TSCAdm-initClient'.
       MOVE 1 TO INIT-CLIENT-FLAG.
 
      * 3. TSCデーモンへの接続
      * (1) TSCDomainの生成
       SET MY-DOMAIN-NAME-PTR TO NULL.
       SET MY-TSCID-PTR TO NULL.
       MOVE 1 TO MY-DOMAIN-FLAG.
       CALL 'TSCDomain-NEW' USING
               BY VALUE     MY-DOMAIN-NAME-PTR
               BY VALUE     MY-TSCID-PTR
               BY VALUE     MY-DOMAIN-FLAG
               BY REFERENCE CORBA-ENVIRONMENT
           RETURNING DOMAIN-PTR.
      * 例外チェック
       IF NOT CORBA-NO-EXCEPTION THEN
           CALL 'OTM-EXCEPTION-HANDLER' USING
                   BY REFERENCE MAJOR
                   BY REFERENCE CORBA-ENVIRONMENT
           CALL 'TSCSysExcept-DELETE' USING
                   BY VALUE EXCEP OF CORBA-ENVIRONMENT
           MOVE 1 TO RETURN-CODE
           GO TO PROG-END
       END-IF.
       DISPLAY 'Success TSCDomain-NEW:DomainName = '
                                           MY-DOMAIN-NAME.
       MOVE 1 TO DOMAIN-CREATE-FLAG.
 
      * (2) TSCClientの取得
       MOVE 1 TO CLIENT-WAY.
       CALL 'TSCAdm-getTSCClient' USING
               BY VALUE     DOMAIN-PTR
               BY VALUE     CLIENT-WAY
               BY REFERENCE CORBA-ENVIRONMENT
           RETURNING CLIENT-PTR.
      * 例外チェック
       IF NOT CORBA-NO-EXCEPTION THEN
           CALL 'OTM-EXCEPTION-HANDLER' USING
                   BY REFERENCE MAJOR
                   BY REFERENCE CORBA-ENVIRONMENT
           CALL 'TSCSysExcept-DELETE' USING
                   BY VALUE EXCEP OF CORBA-ENVIRONMENT
           MOVE 1 TO RETURN-CODE
           GO TO PROG-END
       END-IF.
       DISPLAY 'Success TSCAdm-getTSCClient'.
       MOVE 1 TO GET-CLIENT-FLAG.
 
      * 4. TSCユーザプロキシの生成および各種設定
      *    IDLインタフェース"CBLClass"用のTSCProxy生成
       SET ACCEPTOR-NAME-PTR TO NULL.
       CALL 'CBLClass_TSCprxy-NEW' USING
               BY VALUE     CLIENT-PTR
               BY VALUE     ACCEPTOR-NAME-PTR
               BY REFERENCE CORBA-ENVIRONMENT
           RETURNING PROXY-PTR.
      * 例外チェック
       IF NOT CORBA-NO-EXCEPTION THEN
           CALL 'OTM-EXCEPTION-HANDLER' USING
                   BY REFERENCE MAJOR
                   BY REFERENCE CORBA-ENVIRONMENT
           CALL 'TSCSysExcept-DELETE' USING
                   BY VALUE EXCEP OF CORBA-ENVIRONMENT
           MOVE 1 TO RETURN-CODE
           GO TO PROG-END
       END-IF.
       DISPLAY 'Success CBLClass_TSCprxy-NEW'.
       MOVE 1 TO TSCPRXY-CREATE-FLAG.
 
      * 5. TSCユーザプロキシのメソッド呼び出し
      *    （サーバ側のオブジェクトの呼び出し）
      ****************************************************
      * サーバメソッドの呼び出し
      ****************************************************
       DISPLAY 'Start CBLClass-call'.
       CALL 'CBLClass-call' USING
               BY VALUE     PROXY-PTR
               BY REFERENCE CORBA-ENVIRONMENT.
      * 例外チェック
       IF NOT CORBA-NO-EXCEPTION THEN
           CALL 'OTM-EXCEPTION-HANDLER' USING
                   BY REFERENCE MAJOR
                   BY REFERENCE CORBA-ENVIRONMENT
           IF CORBA-SYSTEM-EXCEPTION THEN
               CALL 'TSCSysExcept-DELETE' USING
                       BY VALUE EXCEP OF CORBA-ENVIRONMENT
               MOVE 1 TO RETURN-CODE
               GO TO PROG-END
           END-IF
      * ユーザ例外受信時の処理
           IF CORBA-USER-EXCEPTION THEN
               CALL 'CORBA-get-exception-name' USING
                       BY REFERENCE EXCEP
                   RETURNING EXCEPTION-NAME-PTR
               MOVE 30 TO EXCEPTION-NAME-LEN
               CALL 'CORBA_string_get' USING
                       BY REFERENCE EXCEPTION-NAME-PTR
                       BY REFERENCE EXCEPTION-NAME-LEN
                       BY REFERENCE EXCEPTION-NAME
               DISPLAY 'Exception-name = ' EXCEPTION-NAME
               CALL 'CORBA-GetExceptionHandle' USING
                       BY REFERENCE EXCEP
                   RETURNING EXCEPTION-HANDLE
               CALL 'GET-value-UserExcept' USING
                       BY VALUE EXCEPTION-HANDLE
                   RETURNING EXCEPTION-VALUE
               DISPLAY 'Exception-value = ' EXCEPTION-VALUE
           END-IF
       END-IF.
       DISPLAY 'Success CBLClass-call'.
 
       PROG-END.
 
      * 6. TSCユーザプロキシの削除
      *    領域の解放
           IF TSCPRXY-CREATE-FLAG = 1 THEN
               CALL 'CBLClass_TSCprxy-DEL' USING
                       BY VALUE PROXY-PTR
                       BY REFERENCE CORBA-ENVIRONMENT
      * 例外チェック
               IF NOT CORBA-NO-EXCEPTION THEN
                   CALL 'OTM-EXCEPTION-HANDLER' USING
                           BY REFERENCE MAJOR
                           BY REFERENCE CORBA-ENVIRONMENT
                   CALL 'TSCSysExcept-DELETE' USING
                           BY VALUE EXCEP OF CORBA-ENVIRONMENT
                   MOVE 1 TO RETURN-CODE
               END-IF
           END-IF.
 
      * 7. TSCデーモンへの接続解放
           IF GET-CLIENT-FLAG = 1 THEN
               CALL 'TSCAdm-releaseTSCClient' USING
                       BY VALUE CLIENT-PTR
                       BY REFERENCE CORBA-ENVIRONMENT
      * 例外チェック
               IF NOT CORBA-NO-EXCEPTION THEN
                   CALL 'OTM-EXCEPTION-HANDLER' USING
                           BY REFERENCE MAJOR
                           BY REFERENCE CORBA-ENVIRONMENT
                   CALL 'TSCSysExcept-DELETE' USING
                           BY VALUE EXCEP OF CORBA-ENVIRONMENT
                   MOVE 1 TO RETURN-CODE
               ELSE
                   DISPLAY 'Success TSCAdm-releaseTSCClient'
               END-IF
           END-IF.
 
           IF DOMAIN-CREATE-FLAG = 1 THEN
               CALL 'TSCDomain-DELETE' USING
                       BY VALUE DOMAIN-PTR
                       BY REFERENCE CORBA-ENVIRONMENT
      * 例外チェック
               IF NOT CORBA-NO-EXCEPTION THEN
                   CALL 'OTM-EXCEPTION-HANDLER' USING
                           BY REFERENCE MAJOR
                           BY REFERENCE CORBA-ENVIRONMENT
                   CALL 'TSCSysExcept-DELETE' USING
                           BY VALUE EXCEP OF CORBA-ENVIRONMENT
                   MOVE 1 TO RETURN-CODE
               END-IF
           END-IF.
 
      * 8. TPBroker OTMの終了処理
           IF INIT-CLIENT-FLAG = 1 THEN
               CALL 'TSCAdm-endClient' USING
                       BY REFERENCE CORBA-ENVIRONMENT
      * 例外チェック
               IF NOT CORBA-NO-EXCEPTION THEN
                   CALL 'OTM-EXCEPTION-HANDLER' USING
                           BY REFERENCE MAJOR
                           BY REFERENCE CORBA-ENVIRONMENT
                   CALL 'TSCSysExcept-DELETE' USING
                           BY VALUE EXCEP OF CORBA-ENVIRONMENT
                   MOVE 1 TO RETURN-CODE
               ELSE
                   DISPLAY 'Success TSCAdm-endClient'
               END-IF
           END-IF.
 
       END PROGRAM CLIENT.

[目次][前へ][次へ]

[他社商品名称に関する表示]

All Rights Reserved. Copyright (C) 2002, 2005, Hitachi, Ltd.