帳票システム構築支援　uCosminexus EUR　uCosminexus EUR Print Manager 帳票出力

[目次][用語][索引][前へ][次へ]

9.11.7　EUR Print Manager - Client Print ActiveX，またはEUR Print Manager - Client Preview ActiveXを自動でインストールして帳票を出力するときのコーディング例

最新のEUR Print Manager - Client Print ActiveX，またはEUR Print Manager - Client Preview ActiveXを自動でインストールして帳票を出力するときのコーディング例です。

クライアントPCに最新のEUR Print Manager - Client Print ActiveX，またはEUR Print Manager - Client Preview ActiveXがインストールされていない場合，クライアントPCの環境に応じてダウンロードパッケージが選択されて，自動でインストールされます。ユーザー単位インストールが可能な環境では，ユーザー単位インストール用のダウンロードパッケージが選択されます。それ以外の環境では，マシン単位インストール用のダウンロードパッケージが選択されます。

EUR Print Manager - Client Print ActiveX，またはEUR Print Manager - Client Preview ActiveXのインストールが完了すると，指定した帳票（EPF形式ファイル）がダウンロードされて，印刷またはプレビュー表示されます。

ダウンロードパッケージ：EUR Print Manager - Adapterのあるマシンに配置
EUR Print Manager - Client Print ActiveX（マシン単位用）：
　http://xxx.xxx.xxx.xxx/machine/EURPMPrintAX.cab"
EUR Print Manager - Client Print ActiveX（ユーザー単位用）：
　http://xxx.xxx.xxx.xxx/user/EURPMPrintAX.cab
EUR Print Manager - Client Preview ActiveX（マシン単位用）：
　http://xxx.xxx.xxx.xxx/machine/EURPMPreViewAX.cab
EUR Print Manager - Client Preview ActiveX（ユーザー単位用）：
　http://xxx.xxx.xxx.xxx/user/EURPMPreViewAX.cab
出力ファイル：EUR Print Manager - Adapterのあるマシンに配置
出力EPF形式ファイル名：http://xxx.xxx.xxx/File/EPF/sample.epf
＜この項の構成＞
(1)　帳票を印刷する場合
(2)　帳票をプレビュー表示する場合

(1)　帳票を印刷する場合

EUR Print Manager - Client Print ActiveXをインストールします。

<%@ LANGUAGE="VBScript" %>
<HTML>
<HEAD>
<META http-equiv="Content-Type"
 content="text/html;charset=Shift_JIS">
<TITLE>
EURPM-CL-AX ASP Sample
</TITLE>
<%
    'Webサーバの処理
    Dim objEURPM
    'EURPMオブジェクト生成
    Set objEURPM=Server.CreateObject("EURPM.Exec")
    Dim strVersion
    'EURPM-CL-AXのバージョン取得
    strVersion = objEURPM.GetPrintAXVersion()
    Dim strClassID
    'EURPM-CL-AXのクラスID取得
    strClassID = objEURPM.GetPrintAXClassID()
%>
</HEAD>
<BODY>
<Script LANGUAGE="vbScript">
<!−
    'クライアントの処理
    Dim CABType  'フラグ
    'OSの判定
    'Windows XPの場合
    if instr( window.navigator.userAgent & "", "NT 5.1" ) <> 0 then
        CABType = 0       'マシン単位インストールフラグ
    else                  '上記以外のOSの場合
        'ブラウザ判定
        'Internet Explorer 7の場合
        if instr( window.navigator.appVersion & "", "MSIE 7" ) <> 0 then
            CABType = 0   'マシン単位インストールフラグ
        else              '上記以外のブラウザの場合
            CABType = 1   'ユーザー単位インストールフラグ
        end if
    end If
 
    Dim CabPath
    'フラグから使用するCAB形式ファイルを決定する
    If CABType = 0 Then
        'マシン単位インストールの格納場所の設定
        CabPath = "http://xxx.xxx.xxx.xxx/machine/EURPMPrintAX.cab"
    Else
        'ユーザー単位インストールの格納場所の設定
        CabPath = "http://xxx.xxx.xxx.xxx/user/EURPMPrintAX.cab"
    End If
 
    'OBJECTタグの生成
    document.Write("<object")
    'Webサーバで取得したクラスIDを指定
    document.Write(" classid=clsid:<%=strClassID%>") 
    'CAB形式ファイルのパスおよびWebサーバで取得したバージョンを指定
    document.Write(" codebase=" & CabPath & "#version=<%=strVersion%>")
    document.Write(" ID=EURPMPRINTAX")
    document.Write(" type=application/x-oleobject>")
    document.Write("<BR>")
    document.Write("<param name=EPFFileURL value=http://xxx.xxx.xxx/File/EPF/sample.epf>")
    document.Write("<BR>")
    document.Write("<param name=LogLevel value=16>")
    document.Write("<BR>")
    document.Write("</object>")
    document.Write("<BR>")
-->
</Script>
</BODY>
</HTML>

(2)　帳票をプレビュー表示する場合

EUR Print Manager - Client Preview ActiveXをインストールします。

<%@ LANGUAGE="VBScript" %>
<HTML>
<HEAD>
<META http-equiv="Content-Type"
 content="text/html;charset=Shift_JIS">
<TITLE>
EURPM-CL-PVX ASP Sample
</TITLE>
<%
'Webサーバの処理
    Dim objEURPM
    'EURPMオブジェクトの生成
    Set objEURPM=Server.CreateObject("EURPM.Exec")
    Dim strVersion
    'EURPM-CL-PVXのバージョン取得
    strVersion = objEURPM.GetPreviewAXVersion()
    Dim strClassID
    'EURPM-CL-PVXのクラスID取得
    strClassID = objEURPM.GetPreviewAXClassID()
%>
</HEAD>
<BODY>
<Script LANGUAGE="vbScript">
<!−
    'クライアントの処理
    Dim CABType  'フラグ
    'OSの判定
    'Windows XPの場合
    if instr( window.navigator.userAgent & "", "NT 5.1" ) <> 0 then
        CABType = 0        'マシン単位インストールフラグ
    else                   '上記以外の場合
        'ブラウザ判定
        'Internet Explorer 7の場合
        if instr( window.navigator.appVersion & "", "MSIE 7" ) <> 0 then
            CABType = 0    'マシン単位インストールフラグ
        else               '上記以外の場合
            CABType = 1    'ユーザー単位インストールフラグ
        end if
    end If
 
    Dim CabPath
    'フラグから使用するCAB形式ファイルを決定する
    If CABType = 0 Then
        'マシン単位インストールの格納場所の設定
        CabPath = "http://xxx.xxx.xxx.xxx/machine/EURPMPreViewAX.cab"
    Else
        'ユーザー単位インストールの格納場所の設定
        CabPath = "http://xxx.xxx.xxx.xxx/user/EURPMPreViewAX.cab"
    End If
 
    'OBJECTタグの記述
    document.Write("<object")
    'Webサーバで取得したクラスIDを指定
    document.Write(" classid=clsid:<%=strClassID%>")
    'CAB形式ファイルのパスおよびWebサーバで取得したバージョンを指定
    document.Write(" codebase=" & CabPath & "#version=<%=strVersion%>")
    document.Write(" ID=EURPMPREVIEWAX")
    document.Write(" width=500")
    document.Write(" height=500")
    document.Write(" type=application/x-oleobject>")
    document.Write("<BR>")
    document.Write("<param name=EPFFileURL value=http://xxx.xxx.xxx/File/EPF/sample.epf>")
    document.Write("<BR>")
    document.Write("<param name=LogLevel value=16>")
    document.Write("<BR>")
    document.Write("</object>")
    document.Write("<BR>")
-->
</Script>
</BODY>
</HTML>

[目次][前へ][次へ]

[他社商品名称に関する表示]

All Rights Reserved. Copyright (C) 2009, 2011, Hitachi, Ltd.
All Rights Reserved. Copyright (C) 2009, 2011, Hitachi Solutions, Ltd.